BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Vector Graphics Lib With Collisions", by darkeagle

use vector graphics easily, and check collisions. useful for if you are doing 2d in 3d and are having trouble with collisions - just set up a basic shape for each sprite you are using, then use VectorsCollide() to check for collisions! even includes scaling and rotation :)

Code

;vector graphics library with collisions
Restore Vectors
Read NumVectors
Dim Vectors(NumVectors,20,10)
LoadVectors()

;v = vector to check
;vx,vy = vector x and y location
;ang = angle of vector
;x,y = x and y point to check
Function InsidePoly( v, vx, vy, ang#, x, y)

Local i, j
     Local bInPoly = 0
     NumPolys = Vectors(v,0,0)

j = NumPolys

For i = 1 To NumPolys
          ix = (Sin(Vectors(V,i,4)+ang#)*Vectors(V,i,5)) + vx
          iy = (Cos(Vectors(V,i,4)+ang#)*Vectors(V,i,5)) + vy
          jx = (Sin(Vectors(V,j,4)+ang#)*Vectors(V,j,5)) + vx
          jy = (Cos(Vectors(V,j,4)+ang#)*Vectors(V,j,5)) + vy
          If x < ( (jx - ix) * (y - iy) / (jy - iy) + ix ) Then
               If iy <= y And y < jy Then
                    bInPoly = 1 - bInPoly
               ElseIf jy <= y And y < iy Then
                    bInPoly = 1 - bInPoly
               EndIf
          EndIf
          
          j = i
     Next

Return bInPoly

End Function

;v1 = first vector
;x1,y1 = x and y of vector
;a1 = angle of first vector
;s1 = scale of first vector
;same for 2
Function VectorsCollide(v1,x1,y1,a1#,s1#,v2,x2,y2,a2#,s2#)

collided = 0

For i = 1 To Vectors(v1,0,0)
     checkx = x1 + (Sin(Vectors(V1,i,4)+a1#)*Vectors(V1,i,5)*s1#)
     checky = y1 + (Cos(Vectors(V1,i,4)+a1#)*Vectors(V1,i,5)*s1#)
     If InsidePolyScale( v2, x2, y2, a2#, checkx, checky, s2#)
          collided = 1
     End If
Next

If collided <> 1
     For i = 1 To Vectors(v2,0,0)
          checkx = x2 + (Sin(Vectors(V2,i,4)+a2#)*Vectors(V2,i,5)*s2#)
          checky = y2 + (Cos(Vectors(V2,i,4)+a2#)*Vectors(V2,i,5)*s2#)
          If InsidePolyScale( v1, x1, y1, a1#, checkx, checky, s1#)
               collided = 1
          End If
     Next
End If

Return collided

End Function

;v = vector to check
;vx,vy = vector x and y location
;ang = angle of vector
;x,y = x and y point to check
;scale = scale of vector
Function InsidePolyScale( v, vx, vy, ang#, x#, y#, scale#=1 )

Local i, j
     Local bInPoly = 0
     NumPolys = Vectors(v,0,0)

j = NumPolys

For i = 1 To NumPolys
          ix = (Sin(Vectors(V,i,4)+ang#)*Vectors(V,i,5)*scale#) + cx + vx
          iy = (Cos(Vectors(V,i,4)+ang#)*Vectors(V,i,5)*scale#) + cy + vy
          jx = (Sin(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#) + cx + vx
          jy = (Cos(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#) + cy + vy
          If x < ( (jx - ix) * (y - iy) / (jy - iy) + ix ) Then
               If iy <= y And y < jy Then
                    bInPoly = 1 - bInPoly
               ElseIf jy <= y And y < iy Then
                    bInPoly = 1 - bInPoly
               EndIf
          EndIf
          
          j = i
     Next

Return bInPoly

End Function

;v = vector to check
;v,v = x and y location
;ang = angle of vector
;scale = scale
Function DrawVector(V,x,y,ang#,scale#=1)

NumPoints = Vectors(V,0,0)

For j = 1 To NumPoints-1
     tx = x + (Sin(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#)
     ty = y + (Cos(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#)
     nx = x + (Sin(Vectors(V,j+1,4)+ang#)*Vectors(V,j+1,5)*scale#)
     ny = y + (Cos(Vectors(V,j+1,4)+ang#)*Vectors(V,j+1,5)*scale#)
     Line tx,ty,nx,ny
Next

If Vectors(V,0,3)
     j = NumPoints
     tx = x + (Sin(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#)
     ty = y + (Cos(Vectors(V,j,4)+ang#)*Vectors(V,j,5)*scale#)
     nx = x + (Sin(Vectors(V,1,4)+ang#)*Vectors(V,1,5)*scale#)
     ny = y + (Cos(Vectors(V,1,4)+ang#)*Vectors(V,1,5)*scale#)
     Line tx,ty,nx,ny
End If

End Function

;load all vectors
Function LoadVectors()

Restore Vectors

Read NumVectors
For i = 1 To NumVectors
     Read Vectors(i,0,0)          ;number of points
     For j = 1 To Vectors(i,0,0)
          Read tx                    ;this point x
          Read ty                    ;this point y
          ;get cartesian co-ords
          Vectors(i,j,1) = tx
          Vectors(i,j,2) = ty
          ;get polar co-ords
          Vectors(i,j,4) = ATan2(Vectors(i,j,1),Vectors(i,j,2))
          Vectors(i,j,5) = Sqr(Vectors(i,j,1)^2+Vectors(i,j,2)^2)
     Next
     Read Vectors(i,0,3)
Next

End Function

;TESTING VECTOR INFO
.Vectors
;1 image
Data 1

;number of points in this image
Data 3
;point locations
Data 0,-10     ;top
Data 5,10
Data -5,10
;connect last point to first point
Data 1

Code software created by Krylar's Kreations