BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Blitz StringList", by thechange

As an example of a linked list, a collection of text lines, like a text file and similar to the StringList in the Windows environment, manually maintained using a set of example functions.

Code

;------------------------------------------------------------------------------;
; A manual maintained linked list in Blitz.
; As an example a collection of text lines, like a text file.
; Similar to the StringList under the Windows environment.

; Each item in the list contains these items.
  Type StringList
    ; The actual text (line).
    Field Text$
    ; And a pointer to the next element in the list, of the same type as the current element ofcourse.
    Field Behind.StringList
  End Type

;<--

; A wrapper function to create a new list, which is a single element to start with.
  Function Create.StringList ( Text$ )
    Local NewItem.StringList = New StringList
    NewItem\Text = Text
    NewItem\Behind = Null
    Return NewItem
  End Function

; A function to append items to the list.
  Function Add ( Root.StringList , Text$ )
    Local FindLast.StringList = Root
    Local PrevItem.StringList = Null
    If Root <> Null
      Repeat
        If FindLast\Behind = Null
          FindLast\Behind = New StringList
          FindLast\Behind\Text = Text
          FindLast\Behind\Behind = Null
          FindLast = FindLast\Behind
          Return
        Else
          PrevItem = FindLast
          FindLast = FindLast\Behind
        End If
      Until FindLast = Null
    End If
  End Function

; And a function to remove any specific items from the list, where the root element is zero.
  Function Remove ( Root.StringList , Element% )
    Local TargetItem.StringList = Root
    Local PrevItem.StringList = Null
    Local Counter% = 0
    If Element > 0
      While Counter < Element And TargetItem <> Null
        Counter = Counter + 1
        PrevItem = TargetItem
        TargetItem = TargetItem\Behind
      Wend
      If TargetItem <> Null
        PrevItem\Behind = TargetItem\Behind
        Delete TargetItem
      End If
    End If
  End Function

; Display all or a specific element from the list.
  Function Display ( Root.StringList , Element% = -1 )
    Local ThisItem.StringList = Root
    Local Counter% = 0
    While ThisItem <> Null
      If Element > -1
        If Element = Counter Then Print Counter + ": " + ThisItem\Text
      Else
        Print Counter + ": " + ThisItem\Text
      End If
      Counter = Counter + 1
      ThisItem = ThisItem\Behind
    Wend
  End Function

; Creating a new collection with only an empty line.
  Local TextFile.StringList = Create ( "" )

;<--

Graphics 800 , 600
  Font = LoadFont ( "Blitz" )
  SetFont Font

; Demonstrating that the collection is (almost) empty at first.
  Color 255 , 255 , 255
  Print "-- Before -- (empty)"
  Color 000 , 000 , 255
  Display TextFile

; Adding some text.
  Add TextFile , "Hello Earth,"
  Add TextFile , ""
  Add TextFile , "We speak on behalf of the global federation"
  Add TextFile , "of the universe. We are pleased to announce"
  Add TextFile , "the destruction of your planet. We dedicate"
  Add TextFile , "all of our precious time to bring glamerous"
  Add TextFile , "annihilation to various meaningless species"
  Add TextFile , "such as yourself."
  Add TextFile , ""
  Add TextFile , "Please do not interpret this condition as a"
  Add TextFile , "threat or attack. It is just a statement of"
  Add TextFile , "fact."
  Add TextFile , ""
  Add TextFile , "Remember that it is every living creature's"
  Add TextFile , "right and preoccupation to die."
  Add TextFile , ""
  Add TextFile , "Greetings."

; And displaying the new collection.
  Color 255 , 255 , 255
  Print "-- After -- (added text)"
  Color 000 , 000 , 255
  Display TextFile

; Modifying the text by removing a few lines here and there.
  For Count% = 1 To 14
    Remove TextFile , 2
  Next

; And displaying the result
  Color 255 , 255 , 255
  Print "-- After After -- (modified text)"
  Color 000 , 000 , 255
  Display TextFile

WaitKey
  End

;-->
;
; If something is unclear, feel free to email me: TheChange@yahoo.com
;
; Have fun :D
;------------------------------------------------------------------------------;

Code software created by Krylar's Kreations