BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Super fast image rotation", by badjim

These functions work a bit like the RotateImage command, but they are fast enough for realtime use. They rotate around the image handle and do not resize the image. They clip some of the image off so you may need a transparent border around the image to prevent vital parts being chopped off.
There are two versions. A two pass version that is fast but has really bad clipping at
90 degree angles, and a three pass version that is slower (but still pretty quick) but doesn't clip too much of the image off at any angle.

Code

Function rotate2pass(img,angle#)
     ;precalc a few values
     gb=GraphicsBuffer()
     buf=ImageBuffer(img)
     width=ImageWidth(img)
     height=ImageHeight(img)
     xhandle=ImageXHandle(img)
     yHandle=ImageYHandle(img)

;This function requires a spare image to work with.
     spare=CreateImage(width,height)
     HandleImage spare,xhandle,yhandle
     sparebuf=ImageBuffer(spare)
     
     ;vertical skew operation
     factor#=Sin(angle)
     sfactor#=1/Cos(angle)
     For y=0 To height
          srcx#=(y-yhandle)*factor
          srcy#=(y-yhandle)/sfactor+yhandle
          desx#=xhandle
          desy#=y+yhandle
          CopyRect srcx,srcy,width,1,desx,desy,buf,sparebuf
     Next
     
     ;clear image
     SetBuffer buf
     Cls
     SetBuffer gb

;horizontal skew operation
     factor#=Sin(angle)/Cos(angle)
     sfactor#=Cos(angle)
     For x=0 To width
          srcx#=(x-xhandle)/sfactor+xhandle
          srcy#=0-(x-xhandle)*factor
          desx#=x+xhandle
          desy#=yhandle
          CopyRect srcx,srcy,1,height,desx,desy,sparebuf,buf
     Next

FreeImage spare
End Function

Function rotate3pass(img,angle#)
     ;precalc a few values
     gb=GraphicsBuffer()
     buf=ImageBuffer(img)
     width=ImageWidth(img)
     height=ImageHeight(img)
     xhandle=ImageXHandle(img)
     yHandle=ImageYHandle(img)

;decide whether to flip image
     If(Cos(angle)>0)
          flip180=1
     Else
          flip180=-1
          angle=angle+180
     EndIf

;This function requires a spare image to work with.
     spare=CopyImage(img)
     sparebuf=ImageBuffer(spare)

;clear image
     SetBuffer buf
     Cls
     SetBuffer gb
     
     ;vertical skew operation
     factor#=(1-Cos(angle))/Sin(angle)
     sfactor#=1
     For y=0 To height
          srcx=(y-yhandle)*factor
          srcy=(y-yhandle)/sfactor+yhandle
          desx=xhandle
          desy=y+yhandle
          CopyRect srcx,srcy,width,1,desx,desy,sparebuf,buf
     Next

;clear spare image
     SetBuffer sparebuf
     Cls
     SetBuffer gb

;horizontal skew operation
     factor#=flip180*Sin(angle)
     sfactor#=flip180
     For x=0 To width
          srcx=(x-xhandle)/sfactor+xhandle
          srcy=0-(x-xhandle)*factor
          desx=x+xhandle
          desy=yhandle
          CopyRect srcx,srcy,1,height,desx,desy,buf,sparebuf
     Next

;clear image
     SetBuffer buf
     Cls
     SetBuffer gb

;vertical skew operation
     factor#=(1-Cos(angle))/Sin(angle)
     sfactor#=flip180
     For y=0 To height
          srcx=(y-yhandle)*factor
          srcy=(y-yhandle)/sfactor+yhandle
          desx=xhandle
          desy=y+yhandle
          CopyRect srcx,srcy,width,1,desx,desy,sparebuf,buf
     Next

FreeImage spare
End Function

Code software created by Krylar's Kreations