BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Return Values Based on Probability ", by shaunsullivan

This include will allow you to add a number of possible outcomes
(string, int or float), and assign each outcome a relative weight. Then, you can call a function that will return an outcome based on the weight.

For example:

prob_init() ; must call init
prob_add_str(10,"shaun")
prob_add_str(40,"collin")
prob_add_str(50,"sam")
local s = prob_roll_str()

; So with the above code it is 10% likely we'll return "shaun", 40% chance we'll return "collin" and 50% chance we'll return "sam"
;(note the weights are just relative, they need not add up to 100)

Code

;
;
; Probability Outcome Generator
; Shaun Sullivan
; shaun@puresim.com
; 
; I just got Blitz3D a few days ago, so there may be better ways to 
; write this code :)
;
; simply include this file at the top of your program 
; 
;
;
Global gPROB_iProbCount = 0
Global gPROB_bCalculatedRolls = False
Global gPROB_iTot = 0
Dim gPROB_iHash(0)

Type tyPROB
     
     Field iOutComeVarType 
     Field iWeight
     Field iVal
     Field sVal$
     Field dVal#
     Field iTag
     
End Type

; Call this before adding a new set of outcomes
Function prob_init()
     
     SeedRnd (MilliSecs())
     gPROB_iProbCount = 0
     gPROB_bCalculatedRolls = False
     gPROB_iTot = 0
     Dim gPROB_iHash(0)
     Delete Each tyPROB
     
End Function

; Call this to return an integer outcome
Function prob_Roll_Int%()

If Not gPROB_bCalculatedRolls Then
          prob_initRolls
     End If

p.tyPROB = PROB_get()
     Return p\iVal
     
End Function

; Call this to return an string outcome
Function prob_Roll_Str$()

If Not gPROB_bCalculatedRolls Then
          prob_initRolls
     End If
     
     p.tyPROB = PROB_get()
     Return p\sVal
                    
End Function

; Call this to return an float outcome
Function prob_Roll_Float#()

If Not gPROB_bCalculatedRolls Then
          prob_initRolls
     End If
     
     p.tyPROB = PROB_get()
     Return p\dVal
     
End Function

; Add an int return value
Function prob_add_int(iWeight%, iVal%)
     
     
     p.tyPROB = PROB_new(iWeight)
     p\iVal = iVal
     
End Function

; Add an str return value
Function prob_add_str(iWeight%, sVal$)
     
     p.tyPROB = PROB_new(iWeight)
     p\sVal = sVal
     
     
End Function

; Add an float return value
Function prob_add_float(iWeight%, dVal#)
     
     p.tyPROB = PROB_new(iWeight)
     p\dVal = dVal

End Function

; Add a new possible return value
Function PROB_new.tyPROB(iWeight)

p.tyPROB = New tyPROB
     p\iWeight = iWeight
     gPROB_iProbCount = gPROB_iProbCount + 1
     p\iTag= gPROB_iProbCount
     Return p

End Function

; Get a probability-based return value
Function PROB_get.tyPROB()

Local iRand = Rand(1, gPROB_iTot)
     Local iTag = gPROB_iHash(iRand)
          
     For p.tyPROB = Each tyPROB
     
          If (p\iTag = iTag) Then
               Return p
          EndIf
          
     Next
     
End Function

; Once the caller asks for its first outcome build a 
; wasteful (but fast)
; lookup table.  We'll use this table to return a value based on the 
; probability weight it was assigned when the caller invoked 
;prob_add_xxx()

Function prob_initRolls()

Local i = 0
     gPROB_iTot = 0
     
     ; First size the lookup array 
     For p.tyPROB = Each tyPROB
          gPROB_iTot = gPROB_iTot + p\iWeight
     Next

Dim gPROB_iHash(gPROB_iTot)
     Local ic = 0
     
     ; Now fill it
     For p.tyPROB = Each tyPROB

Local i2 = 0
          For i2 = 1 To p\iWeight

ic = ic + 1
               gPROB_iHash(ic) = p\iTag

Next
                    
     Next
     
     gPROB_bCalculatedRolls = True
               
End Function

Code software created by Krylar's Kreations