BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Positioning 3d entities in 2d, relative to the camera", by markrosten

A set of functions to try and simplify the positioning of entities using 2d coordinates, relative to camera. Great for HUD objects like scores and overlayed map sprites, etc.

Code

Graphics3D 640,480,16,2
SetBuffer BackBuffer()
 
camera = CreateMyCamera() ;create camera for use with 2d positioning
 
sprite = CreateSprite( cam ) ;create sprite and parent it to camera
EntityColor sprite,255,0,0
 
;resize sprite for 2d display - 32x32 pixels
Resize2dSprite( sprite, 32, 32 )
 
While KeyDown(1)=0
     ;position sprite using 2d coordinates (mousex/y in this example)
     Position2dEntity( sprite, MouseX(), MouseY() )

UpdateWorld
     RenderWorld
     Flip
Wend
EndGraphics
End
 
 
 
;======= ENTITY FUNCTIONS FOR DISPLAYING AND POSITIONING ENTITIES IN 2d =======
 
;by Mark Rosten
;markblitz@planetflibble.com
;based on original code by -norc-
 
;------- CREATE CAMERA (READY FOR USE WITH 2d POSITIONED OBJECTS )
;        parameters: [camzoom#]  - camera zoom factor (optional) (default is 1.0)
;                    [camrange#] - camera range value (optional) (default is 1000)
;                    [parent]    - pointer to camera's new parent entity (optional)
Function CreateMyCamera( camzoom#=1.0, camrange#=1000, parent=0 )
     lcam = CreateCamera( parent )
     CameraZoom lcam, camzoom#
     CameraRange lcam,1,((GraphicsWidth()/2) * camzoom#)+camrange#
     Return lcam
End Function
 
;------- RESIZE SPRITE USED FOR RELATIVE 2d SPACE
;        parameters: ent    - entity handle
;                    width  - width to resize to (in 2d pixels)
;                    height - height to resize to (in 2d pixels)
Function Resize2dSprite( ent, width, height )
     ScaleSprite ent, width/2, height/2
End Function
 
;------- RESIZE ENTITY USED FOR RELATIVE 2d SPACE
;        note: this is for normal meshs as opposed to sprites, should you need it.
;        parameters: ent    - entity handle
;                    width  - width to resize to (in 2d pixels)
;                    height - height to resize to (in 2d pixels)
Function Resize2dEntity( ent, width, height )
     ScaleEntity ent, width/2, height/2, 1
 
     ;you might want to change the Z value. it should be greater than zero though.
End Function
 
;------- POSITION ENTITY IN RELATIVE 2d SPACE
;        note: entity should be parented to a camera so you don't have to keep positioning the entity
;        parameters: ent       - entity handle
;                    x         - relative 2d x coordinate
;                    y         - relative 2d y coordinate
;                   [camzoom#] - camera zoom factor (optional) (default is 1.0)
;        returns: nothing
Function Position2dEntity( ent, x, y, camzoom#=1.0 )
     PositionEntity ent,x-(GraphicsWidth()/2),(GraphicsHeight()/2)-y,(GraphicsWidth()/2) * camzoom#
 
     ;if you want to speed this up (however minutely) you can replace the
     ;GraphicsWitdh()/2 and GraphicsHeight()/2 with global variables or 
     ;constants (if your screen size is fixed)
End Function

Code software created by Krylar's Kreations