BlitzCoder Code Database

BlitzCoder Essentials

•Home Page
•About BlitzCoder
•Contributors
•Terms of Use
•Email Us

Main Areas

•BlitzCoder Chat
•Discussions
•Articles/Tutorials
•Code Database
•Link Database
•Showcase Area
•Worklogs
•Competitions

Special Areas

•Undocumented

Other Blitz Sites

•Blitz Basic Home
•Blitz Showcase
•BlitzPlay Library

BlitzCoder Code Archives Page

Main Codes Page

"Enhanced PlaySound()", by thechange

Using this method you can turn "BBBBBBANG" into "BANG-BANG", e.g. prevent the same sounds from overlapping and keep track of your sounds/channels easily without using excessive processor power. Additional information contained herein.

Code

;-------------------------------------------------------------------------------
;
; This method uses a Type collection of active channels. This collection is not
; automatically updated to preserve precious calculation time. The function
; UpdateChannels() manually updates the channel information in the collection.
; But in most cases this is not required because when playing a new sample using
; the PlaySample() function the collection is automatically updated.
;
; Each channel in the collection contains a SampleID and an Address.
; Address is the channel address used to keep track of the related sample. This
; enables you to change the volume or panning for example. SampleID is explained
; below. To play a sample, you can use the PlaySample() function.
;
;   PlaySample ( Sample , SampleID )
;
; Sample simply identifies the previously loaded sound with LoadSound.
; SampleID identifies two things: First, whether the sound should overlap all
; sounds with the same SampleID or to never let the same sounds overlap each
; other. And secondly giving this sound a (unique) number, enabling you to
; access this sound at any later time. When SampleID is negative, the sound will
; overlap any currently playing sound with the same SampleID. But when the
; SampleID is not negative, the sound will never overlap any currently playing
; sound with the same SampleID.
;
;-------------------------------------------------------------------------------

Type ActiveChannel
    Field SampleID%
    Field Address%
  End Type

Function PlaySample ( SampleAddress% , SampleID% = -1 )
    Local Channel.ActiveChannel
    Local Simultaneous% = False
    Local Playing% = False

If SampleID < 0 Then Simultaneous = True
    For Channel = Each ActiveChannel
      If Channel\SampleID = SampleID Then Playing = True
      If Not ChannelPlaying ( Channel\Address ) Then Delete Channel
    Next
    If Not ( Simultaneous = False And Playing = True )
      Channel = New ActiveChannel
      Channel\SampleID = SampleID
      Channel\Address = PlaySound ( SampleAddress )
    EndIf
  End Function

Function UpdateChannels ()
    Local Channel.ActiveChannel
    For Channel = Each ActiveChannel
      If Not ChannelPlaying ( Channel\Address ) Then Delete Channel
    Next
  End Function

;-------------------------------------------------------------------------------
;
; Below is an example program to display how to use the above functionality.
; Also including 2 functions demonstrating the ability of adding your own
; functionality to this method.
;
;-------------------------------------------------------------------------------

Dim Sample( 3 )  ; Load 3 samples into an array
  Sample( 1 ) = LoadSound ( "Sample1.WAV" )
  Sample( 2 ) = LoadSound ( "Sample2.WAV" )
  Sample( 3 ) = LoadSound ( "Sample3.WAV" )

Repeat
    For Counter = 1 To 3
      If KeyDown ( Counter+1 )  ; Press '1', '2' or '3' to play a sample
        PlaySample Sample( Counter ) , Counter
      EndIf
    Next
    SoundCheck  ; Display channel information
  Until KeyDown ( 1 )  ; Escape to quit
  FlushKeys
  SoundOff  ; Force sound off
End

Function SoundCheck ()  ; Display current channel information
  SetBuffer BackBuffer ()  ; Drawing to background
  Cls  ; Clear background
  Local Channel.ActiveChannel  ; Channel cursor
  Locate 0 , 0  ; Text cursor home
  For Channel = Each ActiveChannel  ; Iterate through collection
    Counter = Counter + 1  ; Assign a channel number for display
    If ChannelPlaying ( Channel\Address )  ; Sample is still playing
      Print "Channel: " + Counter + " Sound: " + Channel\SampleID  ; Display
    End If
  Next
  Flip  ; Swap foreground with background
End Function

Function SoundOff ()  ; Force a 'Sound Off' (a variation of UpdateChannels)
  Local Channel.ActiveChannel  ; Channel cursor
  For Channel = Each ActiveChannel  ; Iterate through channels
    StopChannel Channel\Address  ; Stop playing
    Delete Channel  ; Remove channel from active channels
  Next
End Function

Code software created by Krylar's Kreations