BlitzCoder - Blitz Basic Game Development Resources

BlitzPlus: Moving over to BlitzPlus by Seth Jeffery (cyberseth)

So you've used Blitz2D and Blitz3D, you know the basic commands, but you've now got BlitzPlus and don't know where to start. It was supposed to be amazingly fast but whatever you write just seems to crash or doesn't work, or you can't close the window? We've all been there, so I've written this article to help Blitz+ newcomers get started quickly.

When big difference that Blitz+ handles the program flow instead of previous Blitz versions is in its Events. Every Windows program has events. When you click a button, drag a window, click the X to close it, resize the window... all of these require Windows to update information regarding the window and to redraw it in some form or other. If Blitz hogged the CPU entirely then Windows would never get a look in and it would freeze. :(

So instead we've got something called WaitEvent(). WaitEvent() basically tells Blitz to pass the CPU back to Windows until it's needed, or rather, until the next "event" occurs. If you have a look in the command reference under WaitEvent, you will find among others, the following events:

$101 Key Down - (aka KeyHit)

$102 Key Up

$103 Key Stroke - (aka GetKey)

$201 Mouse Down - (aka MouseHit)

$202 Mouse Up

$203 Mouse Move

$401 Gadget Action - (eg click a button, type text, click a tab)

$803 Window Close - (VERY IMPORTANT)

$1001 Menu Event

$4001 Timer Tick - (ALSO IMPORTANT)

There are others, but these are the most important and the ones you're going to need to remember. $803 is by far the most important because it is the event that occurs when the user clicks the X button on a window. If you want your app to close, you need to do something when this happens, otherwise the window won't disappear! Ok so we know what the events are. Now we need to put them into action. Well, let's first make a window and set up a skeleton for a simple Blitz+ application..

If you copy that into BlitzPlus, it should do something impressive like make a window with a black canvas, which doesn't really do a lot but professes to the world your l33tness and then waits for you to close it. You'll notice also the empty menu bar and status bar there, and that the window is resizable. Well those are the defaults for any window.

But enough of that. We've created a window and a graphics canvas. Now what? We need to get Blitz+ to update the game and draw it, but also have all that fancy frame-limiting stuff that we used to do in previous versions. While the program is in WaitEvent() mode, it's halted so we need to call upon the awesome powers of the TIMER TICK event. ($4001)

To do timer ticks, you first of all create a timer. And, then that's it. Every time the timer ticks over, a TIMER TICK event is called and you can use it to update your game. Voila, frame-limiting. But wait, what if your PC is so slow that the timer ticks more than once. Well, EventData() contains the total number of ticks that have occured in the timer so you gotta use a little variable. Like so:

; Create a standard window at 100,100 of size 400,300
Global win = CreateWindow("H3llo \/\/orld",100,100,400,300)
Global can = CreateCanvas(0,0,ClientWidth(win),ClientHeight(win),win)

; Create a timer at 60FPS, and also a variable for the ticks
Global timer = CreateTimer(60)
Global timerframes

; Store the canvas width/height in variables cause.. well.. its easier
Global canw = ClientWidth(can)
Global canh = ClientHeight(can)

; Here's a variable I'm gonna use to move text along the window
Global txtx = -50

; Repeat this loop forever, or until we end.
Repeat
    ; Wait till something happens
    WaitEvent()
    Select EventID()
    Case $803 ; Window Close
        End
    Case $4001 ; Timer tick
        totalticks = EventData()    ; get the total amount of ticks
                                    ; that the timer has passed
        For tck = timerframes To totalticks
            timerframes=timerframes+1
            UpdateGame()
        Next
        DrawGame()
    End Select
Forever

Function UpdateGame()
    ; UPDATE YOUR GAME HERE
    txtx = txtx + 2   ; move text
End Function

Function DrawGame()
    SetBuffer CanvasBuffer(can)
    Cls
        ; DRAW YOUR GAME HERE
        Text txtx, canh/2, "FEAR ME!", 1, 1   ; vertically centred text
    FlipCanvas can
End Function

And there you have it, an ominous message of terror that runs the same speed on the PC of every mortal that dares to run it.

Well that's the backbone of frame-limiting and events for games in BlitzPlus. Just a few notes on how to speed up your games further still, and some things to consider:

MouseHit() or Event $201? There are two ways for checking for mouse hits and both are valid. The difference is that the Event method will function straight away but the MouseHit() method will be limited to the timing of the game. Also note that there is no MouseDown event. To do that, you will need to use a timer. This rule also applies to "KeyHit() or Event $101?"

LoadImage flags. A new concept in BlitzPlus, LoadImage and CreateImage now have an optional flag parameter. Flag 1 is the default, but it's rubbish and nobody ever uses it. Flag 2 is the fastest, and Flag 4 is slow but it loads the images into RAM, thus conserving Video Memory!

SetGfxDriver. 1=Native, 2=OpenGL, 3=DirectDraw(default). Experiment with them. I find that sometimes Native is faster, sometimes it crashes.

For a printable copy of this article, please click HERE.